Anlegen der Umgebungsdatei »env.cmd«

Java -Implementation finden

Durch die Eingabe des folgenden Kommandos in das Windows -Programm cmd  können wir den Ort der Java -Implementation auf der Festplatte finden.

Eingabe

dir /s/b C:\javac.exe

Es ist zum Erlernen der Android -Programmierung nicht wichtig, dieses dir-Kommando genau zu verstehen, so daß wir hier auf weitere Erläuterung verzichten. Auch bei einigen der folgenden Windows -Kommandodateien verzichten wird aus diesem Grunde auf Erklärungen zu ihrer Implementation.

Es kann einige Minuten dauern, bis dieses Kommando beendet ist. Die Ausgabe hängt von dem System ab, auf welchem das Kommando gestartet wird, und könnte beispielsweise ähnlich wie folgt lauten.

mögliche Ausgabe

C:\Program Files\Java\jdk1.8.0_22\bin\javac.exe
C:\Program Files\Java\jdk1.8.0_27\bin\javac.exe

Für diesen Kurs werden Computer-Grundkenntnisse vorausgesetzt. Daher nehmen wir hier an, daß der Leser den Begriff „Pfad“ bereits kennt.

Als JDK-Pfadsegment  bezeichnen wir hier den Teil der angezeigten Pfade, welcher vor dem Ende »\bin\javac.exe« steht. Oben sind die beiden JDK-Pfadsegmente beispielsweise »C:\Program Files\Java\jdk1.8.0_22« und »C:\Program Files\Java\jdk1.8.0_27«.

Unter allen JDK-Pfadsegmenten wählen wir als JDK-Pfad  nun das JDK-Pfadsegmenten mit der größten Versionsnummer aus, im Falle des obigen Beispiels wär dies also »C:\Program Files\Java\jdk1.8.0_27«. Dabei sollte ein Pfadsegement ausgewählten werden, das mit »C:\Program Files\« oder »C:\Program Files (x86)\« beginnt, also ein Pfadsegment, welches zu installierter Software gehört – keine Pfadsegment, welches zu einer Sicherungskopie oder Ähnlichem gehört.

Dieser JDK-Pfad wird im nächsten Abschnitt benötigt werden.

Anlegen der Umgebungsdatei

Im Arbeitsverzeichnis können die bisher angelegten Dateien nun gelöscht werden.

Im Arbeitsverzeichnis wird nun die Datei »env.cmd« mit dem folgenden Inhalt angelegt.

Dabei wird der im vorigen Absatz ermittelte JDK-Pfad hinter das Gleichheitszeichen in der zweiten Zeile geschrieben.

env.cmd

@COLOR F0
@ECHO %~f0
@SET JDK=C:\Program Files\Java\jdk1.8.0_27
@SET JAVA_HOME=%JDK%
@SET JAVA="%JDK%\bin\java.exe"
@SET JAVAC="%JDK%\bin\javac.exe"
@SET ANDROID_SDK=%LOCALAPPDATA%\android-sdk_r24.0.2-windows\android-sdk-windows
@SET ANDROID_PLATFORM=android-21
@SET EMULATOR="%ANDROID_SDK%\tools\emulator.exe"
@SET SDK=%LOCALAPPDATA%\android-sdk_r24.0.2-windows\android-sdk-windows
@SET PLATFORM=android-21
@SET ADB="%SDK%\platform-tools\adb.exe" -e
@SET AAPT="%SDK%\build-tools\aapt.exe"
@SET DX="%SDK%\build-tools\dx.bat"
@SET SHELL=%ADB% shell
@ECHO EXIT /B 0
@EXIT /B 0

(Falls später ein Java -Programm einmal ohne Konsole gestartet werden soll, kann das »java« in der dritten Zeile auch durch »javaw« ersetzt werden.)

Diese Umgebungsdatei enthält verschiedene Informationen über die Umgebung, die ab nun von anderen Kommandodateien verwendet werden können.

Diese Umgebungsdatei wird in den folgenden Lektionen benötigt, sie ist nicht dafür gedacht, selber direkt gestartet zu werden.

Erproben der Umgebungsdatei

Das folgende Skript »envtry.cmd« erprobt die Umgebungsdatei »env.cmd« und sollte »env try passed.« ausgeben.

envtry.cmd

@ECHO %~f0
@CALL "env.cmd"
@GOTO MAIN

:CREATE
@ECHO public final class EnvTry>EnvTry.java
@ECHO { public static void main( final java.lang.String[] args )>>EnvTry.java
@ECHO.  { java.lang.System.out.println( "env try passed." ); }}>>EnvTry.java
@EXIT /B

:COMPILE
@%JAVAC% EnvTry.java
@EXIT /B

:RUN
@%JAVA% EnvTry
@EXIT /B

:CLEAN
@DEL EnvTry.java
@DEL EnvTry.class
@EXIT /B

:MAIN
@CALL :CREATE
@CALL :COMPILE
@CALL :RUN
@CALL :CLEAN
@PAUSE
@ECHO EXIT
EXIT

Konsole

"…Arbeitsverzeichnis\envtry.cmd"
"…Arbeitsverzeichnis\env.cmd"
EXIT /B 0
env try passed.
Press any key to continue . . .

Das Skript »envtry.cmd« wird nach dem Ende dieser Lektion nicht mehr benötigt. Das Skript »env.cmd« wird später wieder benötigt.